438d311460
The release zip file doesn't contain a top level directory. The previous solution of `sourceRoot = "."` followed by an `installPhase` of `mv * $out/...` does install correctly. However, this grabs detritus from the Nix build sandbox root, in particular `env-vars`, resulting in an accidental run-time dependency on many build-time inputs. Fix by instead using a custom `unpackPhase` to change into an empty directory, then extracting the release and proceeding with the installation from there, so that only files from the release are installed. This reduces closure size by ~425M. Tested that Mission Planner opens and connects to a drone.
90 lines
2.0 KiB
Nix
90 lines
2.0 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchurl,
|
|
makeDesktopItem,
|
|
makeWrapper,
|
|
unzip,
|
|
mono,
|
|
gitUpdater,
|
|
}:
|
|
|
|
let
|
|
pname = "mission-planner";
|
|
desktopItem = makeDesktopItem {
|
|
name = pname;
|
|
exec = pname;
|
|
icon = pname;
|
|
comment = "MissionPlanner GCS & Ardupilot configuration tool";
|
|
desktopName = "MissionPlanner";
|
|
genericName = "Ground Control Station";
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
inherit pname;
|
|
version = "1.3.82";
|
|
|
|
src = fetchurl {
|
|
url = "https://firmware.ardupilot.org/Tools/MissionPlanner/MissionPlanner-${version}.zip";
|
|
sha256 = "sha256-554fFDxHMo4jV3yrPdGgDYQ6XeW+TWdVIIkGQIBdrCQ=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
makeWrapper
|
|
mono
|
|
unzip
|
|
];
|
|
|
|
# zip has no outer directory, so make one and unpack there
|
|
unpackPhase = ''
|
|
runHook preUnpack
|
|
|
|
mkdir -p source
|
|
cd source
|
|
unzip -q $src
|
|
|
|
runHook postUnpack
|
|
'';
|
|
|
|
AOT_FILES = [
|
|
"MissionPlanner.exe"
|
|
"MissionPlanner.*.dll"
|
|
];
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
for file in $AOT_FILES
|
|
do
|
|
mono --aot $file
|
|
done
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/{bin,opt/mission-planner}
|
|
install -m 444 -D mpdesktop150.png $out/share/icons/mission-planner.png
|
|
cp -r ${desktopItem}/share/applications $out/share/
|
|
mv * $out/opt/mission-planner
|
|
makeWrapper ${mono}/bin/mono $out/bin/mission-planner \
|
|
--add-flags $out/opt/mission-planner/MissionPlanner.exe
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.updateScript = gitUpdater { };
|
|
|
|
meta = with lib; {
|
|
description = "ArduPilot ground station";
|
|
mainProgram = "mission-planner";
|
|
longDescription = ''
|
|
Full-featured ground station application for the ArduPilot open source
|
|
autopilot project. Lets you both flash, configure and control ArduPilot
|
|
Plane, Copter and Rover targets.
|
|
'';
|
|
homepage = "https://ardupilot.org/planner/";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ wucke13 ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|