a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
54 lines
1.2 KiB
Nix
54 lines
1.2 KiB
Nix
{
|
|
lib,
|
|
stdenvNoCC,
|
|
fetchFromGitHub,
|
|
curl,
|
|
installShellFiles,
|
|
makeWrapper,
|
|
}:
|
|
|
|
stdenvNoCC.mkDerivation rec {
|
|
pname = "rfc";
|
|
version = "1.0.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "bfontaine";
|
|
repo = "rfc";
|
|
rev = "v${version}";
|
|
hash = "sha256-bCqgLkbZGQFcxhLwekVw+rUGinXTc7QJHlVRGtNf6Jc=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
makeWrapper
|
|
];
|
|
|
|
dontConfigure = true;
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -Dm755 -t $out/bin rfc
|
|
wrapProgram $out/bin/rfc \
|
|
--prefix PATH : ${lib.makeBinPath [ curl ]}
|
|
installManPage man/rfc.1
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Tool to read RFCs from the command line";
|
|
longDescription = ''
|
|
rfc is a little tool written in Bash to read RFCs from the command-line.
|
|
It fetches RFCs and drafts from the Web and caches them locally.
|
|
'';
|
|
homepage = "https://github.com/bfontaine/rfc";
|
|
changelog = "https://github.com/bfontaine/rfc/blob/${src.rev}/CHANGELOG.md";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ azahi ];
|
|
platforms = platforms.all;
|
|
mainProgram = "rfc";
|
|
};
|
|
}
|