a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
77 lines
1.6 KiB
Nix
77 lines
1.6 KiB
Nix
{
|
|
lib,
|
|
buildPackages,
|
|
fetchFromGitHub,
|
|
makeRustPlatform,
|
|
installShellFiles,
|
|
stdenv,
|
|
}:
|
|
|
|
let
|
|
args = rec {
|
|
pname = "cargo-auditable";
|
|
version = "0.6.5";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "rust-secure-code";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-zjv2/qZM0vRyz45DeKRtPHaamv2iLtjpSedVTEXeDr8=";
|
|
};
|
|
|
|
cargoDeps = rustPlatform.fetchCargoVendor {
|
|
inherit pname version src;
|
|
hash = "sha256-oTPGmoGlNfPVZ6qha/oXyPJp94fT2cNlVggbIGHf2bc=";
|
|
};
|
|
|
|
checkFlags = [
|
|
# requires wasm32-unknown-unknown target
|
|
"--skip=test_wasm"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Tool to make production Rust binaries auditable";
|
|
mainProgram = "cargo-auditable";
|
|
homepage = "https://github.com/rust-secure-code/cargo-auditable";
|
|
changelog = "https://github.com/rust-secure-code/cargo-auditable/blob/v${version}/cargo-auditable/CHANGELOG.md";
|
|
license = with licenses; [
|
|
mit # or
|
|
asl20
|
|
];
|
|
maintainers = with maintainers; [ figsoda ];
|
|
broken = stdenv.hostPlatform != stdenv.buildPlatform;
|
|
};
|
|
};
|
|
|
|
rustPlatform = makeRustPlatform {
|
|
inherit (buildPackages) rustc;
|
|
cargo = buildPackages.cargo.override {
|
|
auditable = false;
|
|
};
|
|
};
|
|
|
|
bootstrap = rustPlatform.buildRustPackage (
|
|
args
|
|
// {
|
|
auditable = false;
|
|
}
|
|
);
|
|
in
|
|
|
|
rustPlatform.buildRustPackage.override { cargo-auditable = bootstrap; } (
|
|
args
|
|
// {
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
];
|
|
|
|
postInstall = ''
|
|
installManPage cargo-auditable/cargo-auditable.1
|
|
'';
|
|
|
|
passthru = {
|
|
inherit bootstrap;
|
|
};
|
|
}
|
|
)
|