374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
82 lines
1.9 KiB
Nix
82 lines
1.9 KiB
Nix
{
|
||
lib,
|
||
stdenv,
|
||
fetchurl,
|
||
autoreconfHook,
|
||
libuuid,
|
||
zlib,
|
||
|
||
# tests
|
||
mu,
|
||
perlPackages,
|
||
python3,
|
||
xapian-omega,
|
||
}:
|
||
|
||
let
|
||
generic =
|
||
version: hash:
|
||
stdenv.mkDerivation {
|
||
pname = "xapian";
|
||
inherit version;
|
||
passthru = { inherit version; };
|
||
|
||
src = fetchurl {
|
||
url = "https://oligarchy.co.uk/xapian/${version}/xapian-core-${version}.tar.xz";
|
||
inherit hash;
|
||
};
|
||
|
||
outputs = [
|
||
"out"
|
||
"man"
|
||
"doc"
|
||
];
|
||
|
||
buildInputs = [
|
||
libuuid
|
||
zlib
|
||
];
|
||
nativeBuildInputs = [ autoreconfHook ];
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
doCheck = true;
|
||
|
||
env =
|
||
{
|
||
AUTOMATED_TESTING = true; # https://trac.xapian.org/changeset/8be35f5e1/git
|
||
}
|
||
// lib.optionalAttrs stdenv.hostPlatform.is32bit {
|
||
NIX_CFLAGS_COMPILE = "-fpermissive";
|
||
};
|
||
|
||
# the configure script thinks that Darwin has ___exp10
|
||
# but it’s not available on my systems (or hydra apparently)
|
||
postConfigure = lib.optionalString stdenv.hostPlatform.isDarwin ''
|
||
substituteInPlace config.h \
|
||
--replace "#define HAVE___EXP10 1" "#undef HAVE___EXP10"
|
||
'';
|
||
|
||
passthru.tests = {
|
||
inherit mu xapian-omega;
|
||
inherit (perlPackages) Xapian;
|
||
python-xapian = python3.pkgs.xapian;
|
||
};
|
||
|
||
meta = with lib; {
|
||
description = "Search engine library";
|
||
homepage = "https://xapian.org/";
|
||
changelog = "https://xapian.org/docs/xapian-core-${version}/NEWS";
|
||
license = licenses.gpl2Plus;
|
||
maintainers = with maintainers; [ matthiasbeyer ];
|
||
platforms = platforms.unix;
|
||
};
|
||
};
|
||
in
|
||
{
|
||
# Don't forget to change the hashes in xapian-omega and
|
||
# python3Packages.xapian. They inherit the version from this package, and
|
||
# should always be built with the equivalent xapian version.
|
||
xapian_1_4 = generic "1.4.27" "sha256-vLyZz78WCAEZwlcfwpZ5T1Ob1ULKOSbxfCmZYAgwq2E=";
|
||
}
|