a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
59 lines
1.3 KiB
Nix
59 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
meson,
|
|
ninja,
|
|
python3,
|
|
nix-update-script,
|
|
testers,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "libvarlink";
|
|
version = "24";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "varlink";
|
|
repo = "libvarlink";
|
|
rev = finalAttrs.version;
|
|
sha256 = "sha256-/BWbbDFLxa1da5ewrt3DG/+096dZ+s6p8VdcRGDiEiU=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
python3
|
|
];
|
|
|
|
postPatch = ''
|
|
# test-object: ../lib/test-object.c:129: main: Assertion `setlocale(LC_NUMERIC, "de_DE.UTF-8") != 0' failed.
|
|
# PR that added it https://github.com/varlink/libvarlink/pull/27
|
|
substituteInPlace lib/test-object.c \
|
|
--replace 'assert(setlocale(LC_NUMERIC, "de_DE.UTF-8") != 0);' ""
|
|
|
|
patchShebangs lib/test-symbols.sh varlink-wrapper.py
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
passthru = {
|
|
updateScript = nix-update-script { };
|
|
tests = {
|
|
version = testers.testVersion {
|
|
package = finalAttrs.finalPackage;
|
|
command = "varlink --version";
|
|
};
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "C implementation of the Varlink protocol and command line tool";
|
|
mainProgram = "varlink";
|
|
homepage = "https://github.com/varlink/libvarlink";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ artturin ];
|
|
platforms = platforms.linux;
|
|
};
|
|
})
|