a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
68 lines
1.5 KiB
Nix
68 lines
1.5 KiB
Nix
{
|
|
lib,
|
|
stdenvNoCC,
|
|
fetchFromGitHub,
|
|
makeWrapper,
|
|
curl,
|
|
jq,
|
|
coreutils,
|
|
file,
|
|
}:
|
|
|
|
stdenvNoCC.mkDerivation rec {
|
|
pname = "discord-sh";
|
|
version = "2.0.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ChaoticWeg";
|
|
repo = "discord.sh";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-ZOGhwR9xFzkm+q0Gm8mSXZ9toXG4xGPNwBQMCVanCbY=";
|
|
};
|
|
|
|
# ignore Makefile by disabling buildPhase. Upstream Makefile tries to download
|
|
# binaries from the internet for linting
|
|
dontBuild = true;
|
|
|
|
# discord.sh looks for the .webhook file in the source code directory, which
|
|
# isn't mutable on Nix
|
|
postPatch = ''
|
|
substituteInPlace discord.sh \
|
|
--replace 'thisdir="$(cd "$(dirname "$(readlink -f "''${BASH_SOURCE[0]}")")" && pwd)"' 'thisdir="$(pwd)"'
|
|
'';
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
doInstallCheck = true;
|
|
|
|
installCheckPhase = ''
|
|
runHook preCheck
|
|
$out/bin/discord.sh --help
|
|
runHook postCheck
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -Dm555 discord.sh $out/bin/discord.sh
|
|
wrapProgram $out/bin/discord.sh \
|
|
--set PATH "${
|
|
lib.makeBinPath [
|
|
curl
|
|
jq
|
|
coreutils
|
|
file
|
|
]
|
|
}"
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Write-only command-line Discord webhook integration written in 100% Bash script";
|
|
mainProgram = "discord.sh";
|
|
homepage = "https://github.com/ChaoticWeg/discord.sh";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ matthewcroughan ];
|
|
};
|
|
}
|