a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
63 lines
1.3 KiB
Nix
63 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
makeBinaryWrapper,
|
|
xdg-utils,
|
|
installShellFiles,
|
|
git,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "lab";
|
|
version = "0.25.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "zaquestion";
|
|
repo = "lab";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-VCvjP/bSd/0ywvNWPsseXn/SPkdp+BsXc/jTvB11EOk=";
|
|
};
|
|
|
|
subPackages = [ "." ];
|
|
|
|
vendorHash = "sha256-ChysquNuUffcM3qaWUdqu3Av33gnKkdlotEoFKoedA0=";
|
|
|
|
doCheck = false;
|
|
|
|
nativeBuildInputs = [
|
|
makeBinaryWrapper
|
|
installShellFiles
|
|
];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X main.version=${version}"
|
|
];
|
|
|
|
postInstall = ''
|
|
# create shell completions before wrapProgram so that lab detects the right path for itself
|
|
installShellCompletion --cmd lab \
|
|
--bash <($out/bin/lab completion bash) \
|
|
--fish <($out/bin/lab completion fish) \
|
|
--zsh <($out/bin/lab completion zsh)
|
|
# make xdg-open overrideable at runtime
|
|
wrapProgram $out/bin/lab \
|
|
--suffix PATH ":" "${
|
|
lib.makeBinPath [
|
|
git
|
|
xdg-utils
|
|
]
|
|
}"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Lab wraps Git or Hub, making it simple to clone, fork, and interact with repositories on GitLab";
|
|
homepage = "https://zaquestion.github.io/lab";
|
|
license = licenses.cc0;
|
|
maintainers = [ ];
|
|
mainProgram = "lab";
|
|
};
|
|
}
|