a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
59 lines
1.3 KiB
Nix
59 lines
1.3 KiB
Nix
{
|
||
lib,
|
||
stdenv,
|
||
fetchFromGitHub,
|
||
makeWrapper,
|
||
writeText,
|
||
shellspec,
|
||
# usage:
|
||
# pkgs.mommy.override {
|
||
# mommySettings.sweetie = "catgirl";
|
||
# }
|
||
#
|
||
# $ mommy
|
||
# who's my good catgirl~
|
||
mommySettings ? null,
|
||
}:
|
||
|
||
let
|
||
variables = lib.mapAttrs' (
|
||
name: value: lib.nameValuePair "MOMMY_${lib.toUpper name}" value
|
||
) mommySettings;
|
||
configFile = writeText "mommy-config" (lib.toShellVars variables);
|
||
in
|
||
stdenv.mkDerivation rec {
|
||
pname = "mommy";
|
||
version = "1.6.0";
|
||
|
||
src = fetchFromGitHub {
|
||
owner = "FWDekker";
|
||
repo = "mommy";
|
||
rev = "v${version}";
|
||
hash = "sha256-ZxGHoBRWeGdUelykDdR51HigB85IrvNyswWjCTaOLvg=";
|
||
};
|
||
|
||
nativeBuildInputs = [ makeWrapper ];
|
||
nativeCheckInputs = [ shellspec ];
|
||
installFlags = [ "prefix=$(out)" ];
|
||
|
||
doCheck = true;
|
||
checkTarget = "test/unit";
|
||
|
||
postInstall = ''
|
||
${lib.optionalString (mommySettings != null) ''
|
||
wrapProgram $out/bin/mommy \
|
||
--set-default MOMMY_OPT_CONFIG_FILE "${configFile}"
|
||
''}
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "mommy's here to support you, in any shell, on any system~ ❤️";
|
||
homepage = "https://github.com/FWDekker/mommy";
|
||
changelog = "https://github.com/FWDekker/mommy/blob/v${version}/CHANGELOG.md";
|
||
license = licenses.unlicense;
|
||
platforms = platforms.all;
|
||
maintainers = [ ];
|
||
mainProgram = "mommy";
|
||
};
|
||
}
|