a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
85 lines
2.0 KiB
Nix
85 lines
2.0 KiB
Nix
{
|
|
lib,
|
|
cargo-tauri,
|
|
dbus,
|
|
fetchgit,
|
|
fetchYarnDeps,
|
|
freetype,
|
|
gsettings-desktop-schemas,
|
|
yarnConfigHook,
|
|
nodejs,
|
|
openssl,
|
|
pkg-config,
|
|
rustPlatform,
|
|
webkitgtk_4_1,
|
|
libayatana-appindicator,
|
|
wrapGAppsHook4,
|
|
sqlite,
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "treedome";
|
|
version = "0.5.4";
|
|
|
|
src = fetchgit {
|
|
url = "https://codeberg.org/solver-orgz/treedome";
|
|
rev = version;
|
|
hash = "sha256-fJnrM9I11JKqzrprXa51mJiz9oO5hDp6u69FqJs5l8o=";
|
|
fetchLFS = true;
|
|
};
|
|
|
|
useFetchCargoVendor = true;
|
|
cargoHash = "sha256-scCF4xpc1COdlg57/eNTPdgY7/cJkdcc2s1YNraXzXk=";
|
|
|
|
offlineCache = fetchYarnDeps {
|
|
yarnLock = "${src}/yarn.lock";
|
|
hash = "sha256-in1A1XcfZK5F/EV5CYgfqig+8vKsxd6XhzfSv7Z0nNQ=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace $cargoDepsCopy/libappindicator-sys-*/src/lib.rs \
|
|
--replace-fail "libayatana-appindicator3.so.1" "${libayatana-appindicator}/lib/libayatana-appindicator3.so.1"
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
cargo-tauri.hook
|
|
nodejs
|
|
pkg-config
|
|
wrapGAppsHook4
|
|
yarnConfigHook
|
|
];
|
|
|
|
buildInputs = [
|
|
dbus
|
|
openssl
|
|
freetype
|
|
webkitgtk_4_1
|
|
libayatana-appindicator
|
|
gsettings-desktop-schemas
|
|
sqlite
|
|
];
|
|
|
|
cargoRoot = "src-tauri";
|
|
buildAndTestSubdir = cargoRoot;
|
|
|
|
env = {
|
|
VERGEN_GIT_DESCRIBE = version;
|
|
};
|
|
|
|
# WEBKIT_DISABLE_COMPOSITING_MODE essential in NVIDIA + compositor https://github.com/NixOS/nixpkgs/issues/212064#issuecomment-1400202079
|
|
postFixup = ''
|
|
wrapProgram "$out/bin/treedome" \
|
|
--set WEBKIT_DISABLE_COMPOSITING_MODE 1
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Local-first, encrypted, note taking application organized in tree-like structures";
|
|
homepage = " https://codeberg.org/solver-orgz/treedome";
|
|
license = licenses.agpl3Plus;
|
|
platforms = [ "x86_64-linux" ];
|
|
mainProgram = "treedome";
|
|
maintainers = with maintainers; [ tengkuizdihar ];
|
|
changelog = "https://codeberg.org/solver-orgz/treedome/releases/tag/${version}";
|
|
};
|
|
}
|