a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
71 lines
1.5 KiB
Nix
71 lines
1.5 KiB
Nix
{
|
|
lib,
|
|
argp-standalone,
|
|
callPackage,
|
|
curl,
|
|
fetchFromGitHub,
|
|
gitUpdater,
|
|
meson,
|
|
ninja,
|
|
pkg-config,
|
|
stdenv,
|
|
zstd,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "zchunk";
|
|
version = "1.5.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "zchunk";
|
|
repo = "zchunk";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-X8qywx55TUVEOfYJMV5ARwyUdMjmN4hTmJQ6Upq5zyI=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = [
|
|
curl
|
|
zstd
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [ argp-standalone ];
|
|
|
|
outputs = [
|
|
"out"
|
|
"dev"
|
|
"lib"
|
|
"man"
|
|
];
|
|
|
|
strictDeps = true;
|
|
|
|
passthru = {
|
|
updateScript = gitUpdater { };
|
|
tests = lib.packagesFromDirectoryRecursive {
|
|
inherit callPackage;
|
|
directory = ./tests;
|
|
};
|
|
};
|
|
|
|
meta = {
|
|
homepage = "https://github.com/zchunk/zchunk";
|
|
description = "File format designed for highly efficient deltas while maintaining good compression";
|
|
longDescription = ''
|
|
zchunk is a compressed file format that splits the file into independent
|
|
chunks. This allows you to only download changed chunks when downloading a
|
|
new version of the file, and also makes zchunk files efficient over rsync.
|
|
|
|
zchunk files are protected with strong checksums to verify that the file
|
|
you downloaded is, in fact, the file you wanted.
|
|
'';
|
|
license = lib.licenses.bsd2;
|
|
mainProgram = "zck";
|
|
maintainers = with lib.maintainers; [ ];
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
})
|