a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
57 lines
1.3 KiB
Nix
57 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
buildPythonPackage,
|
|
fetchFromGitHub,
|
|
pythonOlder,
|
|
poetry-core,
|
|
pkg-config,
|
|
pytestCheckHook,
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "pkgconfig";
|
|
version = "1.5.5";
|
|
format = "pyproject";
|
|
|
|
inherit (pkg-config)
|
|
setupHooks
|
|
wrapperName
|
|
suffixSalt
|
|
targetPrefix
|
|
baseBinName
|
|
;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "matze";
|
|
repo = "pkgconfig";
|
|
rev = "v${version}";
|
|
hash = "sha256-uuLUGRNLCR3NS9g6OPCI+qG7tPWsLhI3OE5WmSI3vm8=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace pkgconfig/pkgconfig.py \
|
|
--replace "pkg_config_exe = os.environ.get('PKG_CONFIG', None) or 'pkg-config'" "pkg_config_exe = '${pkg-config}/bin/${pkg-config.targetPrefix}pkg-config'"
|
|
|
|
# those pc files are missing and pkg-config validates that they exist
|
|
substituteInPlace data/fake-openssl.pc \
|
|
--replace "Requires: libssl libcrypto" ""
|
|
'';
|
|
|
|
nativeBuildInputs = [ poetry-core ];
|
|
|
|
# ModuleNotFoundError: No module named 'distutils'
|
|
# https://github.com/matze/pkgconfig/issues/64
|
|
doCheck = pythonOlder "3.12";
|
|
|
|
nativeCheckInputs = [ pytestCheckHook ];
|
|
|
|
pythonImportsCheck = [ "pkgconfig" ];
|
|
|
|
meta = with lib; {
|
|
description = "Interface Python with pkg-config";
|
|
homepage = "https://github.com/matze/pkgconfig";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ nickcao ];
|
|
};
|
|
}
|