a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
65 lines
1.3 KiB
Nix
65 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitLab,
|
|
gitUpdater,
|
|
testers,
|
|
cmake,
|
|
pkg-config,
|
|
gtest,
|
|
doxygen,
|
|
graphviz,
|
|
lomiri,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "properties-cpp";
|
|
version = "0.0.3";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "ubports";
|
|
repo = "development/core/lib-cpp/properties-cpp";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-C/BDEuKNMQHOjATO5aWBptjIlgfv6ykzjFAsHb6uP3Q=";
|
|
};
|
|
|
|
postPatch = lib.optionalString (!finalAttrs.finalPackage.doCheck) ''
|
|
sed -i "/add_subdirectory(tests)/d" CMakeLists.txt
|
|
'';
|
|
|
|
strictDeps = true;
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
doxygen
|
|
graphviz
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = [
|
|
lomiri.cmake-extras
|
|
];
|
|
|
|
checkInputs = [
|
|
gtest
|
|
];
|
|
|
|
doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
|
|
|
|
passthru = {
|
|
tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
|
|
updateScript = gitUpdater { };
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://gitlab.com/ubports/development/core/lib-cpp/properties-cpp";
|
|
description = "Very simple convenience library for handling properties and signals in C++11";
|
|
license = licenses.lgpl3Only;
|
|
maintainers = with maintainers; [ edwtjo ];
|
|
platforms = platforms.linux;
|
|
pkgConfigModules = [
|
|
"properties-cpp"
|
|
];
|
|
};
|
|
})
|