4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a0943687d2a5094a6d92f25a4b6e16a76b5b7
result/bin/apply-formatting $NIXPKGS_PATH
91 lines
2.0 KiB
Nix
91 lines
2.0 KiB
Nix
# This file is based upon upstream's package.nix shared among both
|
|
# "ssh-openpgp-auth" and "sshd-openpgpg-auth"
|
|
{
|
|
lib,
|
|
rustPlatform,
|
|
fetchFromGitea,
|
|
pkg-config,
|
|
just,
|
|
rust-script,
|
|
installShellFiles,
|
|
nettle,
|
|
openssl,
|
|
sqlite,
|
|
stdenv,
|
|
darwin,
|
|
openssh,
|
|
# Arguments not supplied by callPackage
|
|
pname,
|
|
version,
|
|
srcHash,
|
|
cargoHash,
|
|
metaDescription,
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage {
|
|
inherit pname version;
|
|
|
|
src = fetchFromGitea {
|
|
domain = "codeberg.org";
|
|
owner = "wiktor";
|
|
repo = "ssh-openpgp-auth";
|
|
# See also: https://codeberg.org/wiktor/ssh-openpgp-auth/pulls/92#issuecomment-1635274
|
|
rev = "${pname}/${version}";
|
|
hash = srcHash;
|
|
};
|
|
buildAndTestSubdir = pname;
|
|
inherit cargoHash;
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
rustPlatform.bindgenHook
|
|
just
|
|
rust-script
|
|
installShellFiles
|
|
];
|
|
# Otherwise just's build, check and install phases take precedence over
|
|
# buildRustPackage's phases.
|
|
dontUseJustBuild = true;
|
|
dontUseJustCheck = true;
|
|
dontUseJustInstall = true;
|
|
|
|
postInstall = ''
|
|
export HOME=$(mktemp -d)
|
|
just generate manpages ${pname} $out/share/man/man1
|
|
just generate shell_completions ${pname} shell_completions
|
|
installShellCompletion --cmd ${pname} \
|
|
--bash shell_completions/${pname}.bash \
|
|
--fish shell_completions/${pname}.fish \
|
|
--zsh shell_completions/_${pname}
|
|
'';
|
|
|
|
buildInputs =
|
|
[
|
|
nettle
|
|
openssl
|
|
sqlite
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
darwin.apple_sdk_11_0.frameworks.CoreFoundation
|
|
darwin.apple_sdk_11_0.frameworks.IOKit
|
|
darwin.apple_sdk_11_0.frameworks.Security
|
|
darwin.apple_sdk_11_0.frameworks.SystemConfiguration
|
|
];
|
|
|
|
doCheck = true;
|
|
nativeCheckInputs = [
|
|
openssh
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = metaDescription;
|
|
homepage = "https://codeberg.org/wiktor/ssh-openpgp-auth";
|
|
license = with licenses; [
|
|
mit # or
|
|
asl20
|
|
];
|
|
maintainers = with maintainers; [ doronbehar ];
|
|
mainProgram = pname;
|
|
};
|
|
}
|