a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
78 lines
1.5 KiB
Nix
78 lines
1.5 KiB
Nix
{
|
|
lib,
|
|
buildPythonPackage,
|
|
clickhouse-cityhash,
|
|
cython,
|
|
fetchFromGitHub,
|
|
freezegun,
|
|
lz4,
|
|
mock,
|
|
pytestCheckHook,
|
|
pytest-xdist,
|
|
pytz,
|
|
setuptools,
|
|
tzlocal,
|
|
zstd,
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "clickhouse-driver";
|
|
version = "0.2.7";
|
|
format = "setuptools";
|
|
|
|
# pypi source doesn't contain tests
|
|
src = fetchFromGitHub {
|
|
owner = "mymarilyn";
|
|
repo = "clickhouse-driver";
|
|
rev = version;
|
|
hash = "sha256-l0YHWY25PMHgZG/sAZjtGhwmcxWdA8k96zlm9hbKcek=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cython
|
|
setuptools
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
clickhouse-cityhash
|
|
lz4
|
|
pytz
|
|
tzlocal
|
|
zstd
|
|
];
|
|
|
|
nativeCheckInputs = [
|
|
freezegun
|
|
mock
|
|
pytest-xdist
|
|
pytestCheckHook
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace setup.py \
|
|
--replace "lz4<=3.0.1" "lz4<=4"
|
|
'';
|
|
|
|
# remove source to prevent pytest testing source instead of the build artifacts
|
|
# (the source doesn't contain the extension modules)
|
|
preCheck = ''
|
|
rm -rf clickhouse_driver
|
|
'';
|
|
|
|
# some test in test_buffered_reader.py doesn't seem to return
|
|
disabledTestPaths = [ "tests/test_buffered_reader.py" ];
|
|
|
|
# most tests require `clickhouse`
|
|
# TODO: enable tests after `clickhouse` unbroken
|
|
doCheck = false;
|
|
|
|
pythonImportsCheck = [ "clickhouse_driver" ];
|
|
|
|
meta = with lib; {
|
|
description = "Python driver with native interface for ClickHouse";
|
|
homepage = "https://github.com/mymarilyn/clickhouse-driver";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ breakds ];
|
|
};
|
|
}
|