a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
39 lines
1.0 KiB
Nix
39 lines
1.0 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
autoreconfHook,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libiscsi";
|
|
version = "1.20.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "sahlberg";
|
|
repo = "libiscsi";
|
|
rev = version;
|
|
sha256 = "sha256-idiK9JowKhGAk5F5qJ57X14Q2Y0TbIKRI02onzLPkas=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace lib/socket.c \
|
|
--replace-fail "void iscsi_decrement_iface_rr() {" "void iscsi_decrement_iface_rr(void) {"
|
|
'';
|
|
|
|
nativeBuildInputs = [ autoreconfHook ];
|
|
|
|
env = lib.optionalAttrs (stdenv.hostPlatform.is32bit || stdenv.hostPlatform.isDarwin) {
|
|
# iscsi-discard.c:223:57: error: format specifies type 'unsigned long' but the argument has type 'uint64_t' (aka 'unsigned long long') [-Werror,-Wformat]
|
|
NIX_CFLAGS_COMPILE = "-Wno-error=format";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "iscsi client library and utilities";
|
|
homepage = "https://github.com/sahlberg/libiscsi";
|
|
license = licenses.lgpl2;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ misuzu ];
|
|
};
|
|
}
|