e19b462acf
These packages were previously maintained by primeos who became inactive and was removed in #415587, leaving some packages without a maintainer. I'm taking over maintenance for these packages that I'm interested in: - swayidle - swaylock - wayland-utils - wev - wlsunset - wayland-protocols
74 lines
2.0 KiB
Nix
74 lines
2.0 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchurl,
|
|
pkg-config,
|
|
meson,
|
|
ninja,
|
|
wayland-scanner,
|
|
python3,
|
|
wayland,
|
|
gitUpdater,
|
|
testers,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "wayland-protocols";
|
|
version = "1.45";
|
|
|
|
doCheck =
|
|
stdenv.hostPlatform == stdenv.buildPlatform
|
|
&&
|
|
# https://gitlab.freedesktop.org/wayland/wayland-protocols/-/issues/48
|
|
stdenv.hostPlatform.linker == "bfd"
|
|
&& lib.meta.availableOn stdenv.hostPlatform wayland;
|
|
|
|
src = fetchurl {
|
|
url = "https://gitlab.freedesktop.org/wayland/${finalAttrs.pname}/-/releases/${finalAttrs.version}/downloads/${finalAttrs.pname}-${finalAttrs.version}.tar.xz";
|
|
hash = "sha256-TSsqnj4JnQF9yBB78cM00nu4fZ5K/xmgyNhW0XzUHvA=";
|
|
};
|
|
|
|
postPatch = lib.optionalString finalAttrs.finalPackage.doCheck ''
|
|
patchShebangs tests/
|
|
'';
|
|
|
|
depsBuildBuild = [ pkg-config ];
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
wayland-scanner
|
|
];
|
|
nativeCheckInputs = [
|
|
python3
|
|
wayland
|
|
];
|
|
checkInputs = [ wayland ];
|
|
strictDeps = true;
|
|
|
|
mesonFlags = [ "-Dtests=${lib.boolToString finalAttrs.finalPackage.doCheck}" ];
|
|
|
|
meta = {
|
|
description = "Wayland protocol extensions";
|
|
longDescription = ''
|
|
wayland-protocols contains Wayland protocols that add functionality not
|
|
available in the Wayland core protocol. Such protocols either add
|
|
completely new functionality, or extend the functionality of some other
|
|
protocol either in Wayland core, or some other protocol in
|
|
wayland-protocols.
|
|
'';
|
|
homepage = "https://gitlab.freedesktop.org/wayland/wayland-protocols";
|
|
license = lib.licenses.mit; # Expat version
|
|
platforms = lib.platforms.all;
|
|
maintainers = with lib.maintainers; [ rewine ];
|
|
pkgConfigModules = [ "wayland-protocols" ];
|
|
};
|
|
|
|
passthru.updateScript = gitUpdater {
|
|
url = "https://gitlab.freedesktop.org/wayland/wayland-protocols.git";
|
|
};
|
|
passthru.version = finalAttrs.version;
|
|
passthru.tests.pkg-config = testers.hasPkgConfigModules {
|
|
package = finalAttrs.finalPackage;
|
|
};
|
|
})
|