a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
59 lines
1.3 KiB
Nix
59 lines
1.3 KiB
Nix
{
|
|
cmake,
|
|
fetchFromGitHub,
|
|
lib,
|
|
llvmPackages,
|
|
python ? null,
|
|
stdenv,
|
|
swig,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "plfit";
|
|
version = "1.0.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ntamas";
|
|
repo = "plfit";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-0JrPAq/4yzr7XbxvcnFj8CKmMyZT05PkSdGprNdAsJA=";
|
|
};
|
|
|
|
postPatch = lib.optionalString (python != null) ''
|
|
substituteInPlace src/CMakeLists.txt \
|
|
--replace-fail ' ''${Python3_SITEARCH}' ' ${placeholder "out"}/${python.sitePackages}' \
|
|
--replace-fail ' ''${Python3_SITELIB}' ' ${placeholder "out"}/${python.sitePackages}'
|
|
'';
|
|
|
|
nativeBuildInputs =
|
|
[
|
|
cmake
|
|
]
|
|
++ lib.optionals (python != null) [
|
|
python
|
|
swig
|
|
];
|
|
|
|
cmakeFlags =
|
|
[
|
|
"-DPLFIT_USE_OPENMP=ON"
|
|
]
|
|
++ lib.optionals (python != null) [
|
|
"-DPLFIT_COMPILE_PYTHON_MODULE=ON"
|
|
];
|
|
|
|
buildInputs = lib.optionals stdenv.cc.isClang [
|
|
llvmPackages.openmp
|
|
];
|
|
|
|
doCheck = true;
|
|
|
|
meta = {
|
|
description = "Fitting power-law distributions to empirical data";
|
|
homepage = "https://github.com/ntamas/plfit";
|
|
changelog = "https://github.com/ntamas/plfit/blob/${finalAttrs.src.rev}/CHANGELOG.md";
|
|
license = lib.licenses.gpl2Plus;
|
|
maintainers = with lib.maintainers; [ dotlambda ];
|
|
};
|
|
})
|