9833d56c24
Done with the help of https://github.com/Mindavi/nixpkgs-mark-broken Tool is still WIP but this is one of the first results. I manually audited the results and removed some results that were not valid. Note that some of these packages maybe should have more constrained platforms set instead of broken set, but I think not being perfectly correct is better than just keep trying to build all these things and never succeeding. Some observations: - Some darwin builds require XCode tools - aarch64-linux builds sometimes suffer from using gcc9 - gcc9 is getting older and misses some new libraries/features - Sometimes tools try to do system detection or expect some explicit settings for platforms that are not x86_64-linux
38 lines
1.3 KiB
Nix
38 lines
1.3 KiB
Nix
{ lib, stdenv, fetchurl }:
|
|
|
|
# libhdhomerun requires UDP port 65001 to be open in order to detect and communicate with tuners.
|
|
# If your firewall is enabled, make sure to have something like:
|
|
# networking.firewall.allowedUDPPorts = [ 65001 ];
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libhdhomerun";
|
|
version = "20220303";
|
|
|
|
src = fetchurl {
|
|
url = "https://download.silicondust.com/hdhomerun/libhdhomerun_${version}.tgz";
|
|
sha256 = "sha256-HlT/78LUiTkRUB2jHmYrnQY+bBiv4stcZlMyUnelSpc=";
|
|
};
|
|
|
|
patchPhase = lib.optionalString stdenv.isDarwin ''
|
|
substituteInPlace Makefile --replace "gcc" "cc"
|
|
substituteInPlace Makefile --replace "-arch i386" ""
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/{bin,lib,include/hdhomerun}
|
|
install -Dm444 libhdhomerun${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib
|
|
install -Dm555 hdhomerun_config $out/bin
|
|
cp *.h $out/include/hdhomerun
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Implements the libhdhomerun protocol for use with Silicondust HDHomeRun TV tuners";
|
|
homepage = "https://www.silicondust.com/support/linux";
|
|
license = licenses.lgpl21Only;
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.titanous ];
|
|
# never built on aarch64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.isDarwin && stdenv.isAarch64;
|
|
};
|
|
}
|