a19cd4ffb1
This reverts commit 65a333600d5c88a98d674f637d092807cfc12253. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 / 758551e4587d75882aebc21a04bee960418f8ce9
67 lines
1.5 KiB
Nix
67 lines
1.5 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
replaceVars,
|
|
installShellFiles,
|
|
testers,
|
|
org-stats,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "org-stats";
|
|
version = "1.12.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "caarlos0";
|
|
repo = "org-stats";
|
|
rev = "v${version}";
|
|
hash = "sha256-QTjJ+4Qu5u+5ZCoIAQBxqdhjNI2CXUB8r2Zx8xfIiGw=";
|
|
};
|
|
|
|
vendorHash = "sha256-0biuv94wGXiME181nlkvozhB+x4waGMgwXD9ColQWPw=";
|
|
|
|
patches = [
|
|
# patch in version information
|
|
# since `debug.ReadBuildInfo` does not work with `go build
|
|
(replaceVars ./version.patch {
|
|
inherit version;
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
];
|
|
|
|
postInstall = ''
|
|
$out/bin/org-stats man > org-stats.1
|
|
installManPage org-stats.1
|
|
|
|
installShellCompletion --cmd org-stats \
|
|
--bash <($out/bin/org-stats completion bash) \
|
|
--fish <($out/bin/org-stats completion fish) \
|
|
--zsh <($out/bin/org-stats completion zsh)
|
|
'';
|
|
|
|
passthru.tests = {
|
|
version = testers.testVersion {
|
|
package = org-stats;
|
|
command = "org-stats version";
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Get the contributor stats summary from all repos of any given organization";
|
|
homepage = "https://github.com/caarlos0/org-stats";
|
|
changelog = "https://github.com/caarlos0/org-stats/releases/tag/${src.rev}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ figsoda ];
|
|
mainProgram = "org-stats";
|
|
};
|
|
}
|