c8330c9972
My original commit was somewhat more tongue in cheek, but I think this time I'm going to be honest, rather than hiding behind humor. I'm angry that we as a community have reached a point where we're falling apart because people would rather accept sealioning and bad faith arguments that belong in a 2002 mailing list, not a 2024 software community. Every time I dare come back to the Nix community as a more active contributor it feels like we have a fresh wave of controversy that we don't ever heal from, everyone just moves on, more tired, and more broken than before. And now it's crossed a line. I'm out. I hope the community decides to actually try and heal. Tolerating the intolerant for too long has consequences - and the [paradox of tolerance](https://en.wikipedia.org/wiki/Paradox_of_tolerance) has come to its natural conclusion here. If it does heal, I'll be back with a vengeance, because it turns out replacing Nix is hard - emotionally and technically, and I'll miss it. ~Danielle (this commit+PR are not a place for useless debates.)
82 lines
1.9 KiB
Nix
82 lines
1.9 KiB
Nix
{ lib
|
|
, fetchFromGitHub
|
|
, python3
|
|
, asciidoc
|
|
, cacert
|
|
, docbook_xsl
|
|
, installShellFiles
|
|
, libxml2
|
|
, libxslt
|
|
, testers
|
|
, offlineimap
|
|
, fetchpatch
|
|
}:
|
|
|
|
python3.pkgs.buildPythonApplication rec {
|
|
pname = "offlineimap";
|
|
version = "8.0.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "OfflineIMAP";
|
|
repo = "offlineimap3";
|
|
rev = "v${version}";
|
|
sha256 = "0y3giaz9i8vvczlxkbwymfkn3vi9fv599dy4pc2pn2afxsl4mg2w";
|
|
};
|
|
|
|
patches = [
|
|
(fetchpatch {
|
|
name = "sqlite-version-aware-threadsafety-check.patch";
|
|
url = "https://github.com/OfflineIMAP/offlineimap3/pull/139/commits/7cd32cf834b34a3d4675b29bebcd32dc1e5ef128.patch";
|
|
hash = "sha256-xNq4jFHMf9XZaa9BFF1lOzZrEGa5BEU8Dr+gMOBkJE4=";
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
asciidoc
|
|
docbook_xsl
|
|
installShellFiles
|
|
libxml2
|
|
libxslt
|
|
];
|
|
|
|
propagatedBuildInputs = with python3.pkgs; [
|
|
certifi
|
|
distro
|
|
imaplib2
|
|
pysocks
|
|
rfc6555
|
|
urllib3
|
|
];
|
|
|
|
postPatch = ''
|
|
# Skip xmllint to stop failures due to no network access
|
|
sed -i docs/Makefile -e "s|a2x -v -d |a2x -L -v -d |"
|
|
|
|
# Provide CA certificates (Used when "sslcacertfile = OS-DEFAULT" is configured")
|
|
sed -i offlineimap/utils/distro_utils.py -e '/def get_os_sslcertfile():/a\ \ \ \ return "${cacert}/etc/ssl/certs/ca-bundle.crt"'
|
|
'';
|
|
|
|
postInstall = ''
|
|
make -C docs man
|
|
installManPage docs/offlineimap.1
|
|
installManPage docs/offlineimapui.7
|
|
'';
|
|
|
|
# Test requires credentials
|
|
doCheck = false;
|
|
|
|
pythonImportsCheck = [
|
|
"offlineimap"
|
|
];
|
|
|
|
passthru.tests.version = testers.testVersion { package = offlineimap; };
|
|
|
|
meta = with lib; {
|
|
description = "Synchronize emails between two repositories, so that you can read the same mailbox from multiple computers";
|
|
homepage = "http://offlineimap.org";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ ];
|
|
mainProgram = "offlineimap";
|
|
};
|
|
}
|