aabd7c4da0
Diff: https://github.com/VSCodium/vscodium/compare/1.88.1.24104...1.90.0.24158 Signed-off-by: Ludovico Piero <lewdovico@gnuweeb.org>
69 lines
2.6 KiB
Nix
69 lines
2.6 KiB
Nix
{ lib, stdenv, callPackage, fetchurl, nixosTests, commandLineArgs ? "", useVSCodeRipgrep ? stdenv.isDarwin }:
|
|
|
|
let
|
|
inherit (stdenv.hostPlatform) system;
|
|
throwSystem = throw "Unsupported system: ${system}";
|
|
|
|
plat = {
|
|
x86_64-linux = "linux-x64";
|
|
x86_64-darwin = "darwin-x64";
|
|
aarch64-linux = "linux-arm64";
|
|
aarch64-darwin = "darwin-arm64";
|
|
armv7l-linux = "linux-armhf";
|
|
}.${system} or throwSystem;
|
|
|
|
archive_fmt = if stdenv.isDarwin then "zip" else "tar.gz";
|
|
|
|
sha256 = {
|
|
x86_64-linux = "1zmgvadhsnsbmqb559kvf66i7h6iq7vw99m7vdxcfmdl6c1pwyvb";
|
|
x86_64-darwin = "061h423vay3d28d2015llz7pwlqcrjy0lmw47xgy3iy6hfadrra2";
|
|
aarch64-linux = "0n288h6369bazykp6jyapi6yz0k7nivql6wz68fgkagfdyxzl1yb";
|
|
aarch64-darwin = "13k9hvbzj8xyfi29g0x4nz80gmjq3s693zi5fi4lbf4bj7jmcamq";
|
|
armv7l-linux = "19p6k1rgy83vs76hksjx5d4v32jq31r6aw5kzcc8gsq114xj9c2a";
|
|
}.${system} or throwSystem;
|
|
|
|
sourceRoot = lib.optionalString (!stdenv.isDarwin) ".";
|
|
in
|
|
callPackage ./generic.nix rec {
|
|
inherit sourceRoot commandLineArgs useVSCodeRipgrep;
|
|
|
|
# Please backport all compatible updates to the stable release.
|
|
# This is important for the extension ecosystem.
|
|
version = "1.90.0.24158";
|
|
pname = "vscodium";
|
|
|
|
executableName = "codium";
|
|
longName = "VSCodium";
|
|
shortName = "vscodium";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/VSCodium/vscodium/releases/download/${version}/VSCodium-${plat}-${version}.${archive_fmt}";
|
|
inherit sha256;
|
|
};
|
|
|
|
tests = nixosTests.vscodium;
|
|
|
|
updateScript = ./update-vscodium.sh;
|
|
|
|
meta = with lib; {
|
|
description = ''
|
|
Open source source code editor developed by Microsoft for Windows,
|
|
Linux and macOS (VS Code without MS branding/telemetry/licensing)
|
|
'';
|
|
longDescription = ''
|
|
Open source source code editor developed by Microsoft for Windows,
|
|
Linux and macOS. It includes support for debugging, embedded Git
|
|
control, syntax highlighting, intelligent code completion, snippets,
|
|
and code refactoring. It is also customizable, so users can change the
|
|
editor's theme, keyboard shortcuts, and preferences
|
|
'';
|
|
homepage = "https://github.com/VSCodium/vscodium";
|
|
downloadPage = "https://github.com/VSCodium/vscodium/releases";
|
|
license = licenses.mit;
|
|
sourceProvenance = with sourceTypes; [ binaryNativeCode ];
|
|
maintainers = with maintainers; [ synthetica bobby285271 ludovicopiero ];
|
|
mainProgram = "codium";
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" "armv7l-linux" ];
|
|
};
|
|
}
|