organic/nix/package.nix

{
  hello,
  lib,
  pkgs,
  rust-overlay,

  targetBins ? [ ],
  features ? [ ],
  cargoBuildTarget ? null,
  buildType ? null,
  buildLib ? false,
}:
let
  cargoToml = (lib.importTOML ../Cargo.toml);
  rustPlatformFor =
    pkgs:
    let
      rust-bin = rust-overlay.lib.mkRustBin { } pkgs;
      rustToolchain = (rust-bin.fromRustupToolchainFile ../rust-toolchain.toml).override (
        if cargoBuildTarget != null then
          {
            targets = [ cargoBuildTarget ];
          }
        else
          { }
      );
      baseRustPlatform = (
        pkgs.makeRustPlatform {
          cargo = rustToolchain;
          rustc = rustToolchain;
        }
      );
      rustPlatform =
        if cargoBuildTarget != null then
          baseRustPlatform.overrideScope (
            final: prev: {
              cargoBuildHook = prev.cargoBuildHook.overrideDerivation (_: {
                rustcTargetSpec = cargoBuildTarget;
              });
              cargoInstallHook = hello;
            }
          )
        else
          baseRustPlatform;
    in
    rustPlatform;
in
(rustPlatformFor pkgs).buildRustPackage (
  # rustPlatform.buildRustPackage (
  {
    pname = "organic";
    version = cargoToml.package.version;
    src = lib.cleanSource ../.;

    cargoLock.lockFile = ../Cargo.lock;

    cargoBuildFlags = builtins.concatLists [
      (builtins.concatMap (targetBin: [
        "--bin"
        targetBin
      ]) targetBins)
      (if buildLib then [ "--lib" ] else [ ])
      (
        if features != [ ] then
          [
            "--features"
            (builtins.concatStringsSep " " features)
          ]
        else
          [ ]
      )
    ];
  }
  // (
    if buildType != null then
      {
        buildType = buildType;
      }
    else
      { }
  )
)