Add support for building organic via nix.

.gitignore

@@ -1,3 +1,3 @@
 /target
-Cargo.lock
 TODO.org
+/result

Cargo.toml

@@ -1,5 +1,4 @@
 # cargo-features = ["profile-rustflags"]
-cargo-features = ["codegen-backend"]
 
 [package]
 name = "organic"
@@ -104,9 +103,5 @@ inherits = "release"
 lto = true
 strip = true
 
-[profile.dev]
-codegen-backend = "cranelift"
-
 [profile.dev.package."*"]
-codegen-backend = "llvm"
 opt-level = 3

flake.lock

@@ -0,0 +1,48 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1780749050,
+        "narHash": "sha256-3av0pIjlOWQ6rDbNOmpUSvbNnJkGORQKKjb4LtCZsIY=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "a799d3e3886da994fa307f817a6bc705ae538eeb",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs",
+        "rust-overlay": "rust-overlay"
+      }
+    },
+    "rust-overlay": {
+      "inputs": {
+        "nixpkgs": [
+          "nixpkgs"
+        ]
+      },
+      "locked": {
+        "lastModified": 1781407245,
+        "narHash": "sha256-VzJq4MmD0uyNDAceudSe1hHqcQMe9Tau0U4S+5iRGh0=",
+        "owner": "oxalica",
+        "repo": "rust-overlay",
+        "rev": "d5f483210eb016d66102eef22baa128b3b3233fc",
+        "type": "github"
+      },
+      "original": {
+        "owner": "oxalica",
+        "repo": "rust-overlay",
+        "type": "github"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,139 @@
+{
+  description = "Organic Org parser";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+      };
+    };
+  };
+
+  outputs =
+    {
+      self,
+      nixpkgs,
+      rust-overlay,
+    }:
+    let
+      forAllSystems =
+        func:
+        builtins.listToAttrs (
+          map (system: {
+            name = system;
+            value = func system;
+          }) nixpkgs.lib.systems.flakeExposed
+        );
+    in
+    {
+      devShells = forAllSystems (
+        system:
+        let
+          overlays = [ (import rust-overlay) ];
+          pkgs = import nixpkgs {
+            inherit system overlays;
+          };
+          rustToolchain =
+            (pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml).override
+              { targets = [ "wasm32-unknown-unknown" ]; };
+        in
+        {
+          default = pkgs.mkShell {
+            nativeBuildInputs = [
+              rustToolchain
+            ];
+            buildInputs = with pkgs; [
+              wasm-bindgen-cli
+            ];
+          };
+        }
+      );
+      packages = forAllSystems (
+        system:
+        let
+          overlays = [ (import rust-overlay) ];
+          pkgs = import nixpkgs {
+            inherit system overlays;
+          };
+          build_wasm =
+            {
+              bindgenTarget ? null,
+            }:
+            (pkgs.callPackage ./nix/package.nix {
+              targetBins = [
+                "wasm"
+              ];
+              features = [ "wasm" ];
+              cargoBuildTarget = "wasm32-unknown-unknown";
+              buildType = "wasm";
+            }).overrideAttrs
+              (
+                old:
+                let
+                  bindgen_command = [
+                    "${pkgs.wasm-bindgen-cli}/bin/wasm-bindgen"
+                    "--target"
+                    bindgenTarget
+                    "--out-dir"
+                    "target/wasm32-unknown-unknown/${bindgenTarget}"
+                    "target/wasm32-unknown-unknown/wasm/wasm.wasm"
+                  ];
+                in
+                {
+                  postBuild = ''
+                    ${pkgs.lib.escapeShellArgs bindgen_command}
+                  '';
+
+                  installPhase = ''
+                    mkdir -p $out/share/${bindgenTarget}
+                    cp target/wasm32-unknown-unknown/${bindgenTarget}/* $out/share/${bindgenTarget}
+                  '';
+                }
+              );
+        in
+        rec {
+          all = pkgs.symlinkJoin {
+            name = "all";
+            paths = [
+              library
+              devTools
+              wasm_bundler
+              wasm_web
+            ];
+          };
+          library = (pkgs.callPackage ./nix/package.nix { buildLib = true; }).overrideAttrs (
+            old:
+            let
+            in
+            {
+              installPhase = ''
+                mkdir -p $out/lib
+                cp target/*/release/liborganic.rlib $out/lib/
+              '';
+            }
+          );
+          devTools = pkgs.callPackage ./nix/package.nix {
+            targetBins = [
+              "parse"
+              "compare"
+            ];
+            features = [ "compare" ];
+          };
+          wasm_bundler = build_wasm { bindgenTarget = "bundler"; };
+          wasm_web = build_wasm { bindgenTarget = "web"; };
+          docker_env = pkgs.buildEnv {
+            name = "organic";
+            paths = with pkgs; [
+              devTools
+              bash
+              uutils-coreutils-noprefix
+              # toybox # Smaller than uutils-coreutils?
+            ];
+          };
+          default = all;
+        }
+      );
+    };
+}

nix/package.nix

@@ -0,0 +1,75 @@
+{
+  hello,
+  lib,
+  makeRustPlatform,
+  pkgsBuildHost,
+
+  targetBins ? [ ],
+  features ? [ ],
+  cargoBuildTarget ? null,
+  buildType ? null,
+  buildLib ? false,
+}:
+let
+  cargoToml = (lib.importTOML ../Cargo.toml);
+  rustToolchain = (pkgsBuildHost.rust-bin.fromRustupToolchainFile ../rust-toolchain.toml).override (
+    if cargoBuildTarget != null then
+      {
+        targets = [ cargoBuildTarget ];
+      }
+    else
+      { }
+  );
+  baseRustPlatform = (
+    makeRustPlatform {
+      cargo = rustToolchain;
+      rustc = rustToolchain;
+    }
+  );
+  rustPlatform =
+    if cargoBuildTarget != null then
+      baseRustPlatform.overrideScope (
+        final: prev: {
+          cargoBuildHook = prev.cargoBuildHook.overrideDerivation (_: {
+            rustcTargetSpec = cargoBuildTarget;
+          });
+          cargoInstallHook = hello;
+        }
+      )
+    else
+      baseRustPlatform;
+in
+rustPlatform.buildRustPackage (
+  {
+    pname = "organic";
+    version = cargoToml.package.version;
+    src = lib.cleanSource ../.;
+
+    cargoLock.lockFile = ../Cargo.lock;
+
+    cargoBuildFlags = builtins.concatLists [
+      (builtins.concatMap (targetBin: [
+        "--bin"
+        targetBin
+      ]) targetBins)
+      (if buildLib then [ "--lib" ] else [ ])
+      (
+        if features != [ ] then
+          [
+            "--features"
+            (builtins.concatStringsSep " " features)
+          ]
+        else
+          [ ]
+      )
+    ];
+  }
+  // (
+    if buildType != null then
+      {
+        buildType = buildType;
+      }
+    else
+      { }
+  )
+)

rust-toolchain.toml

@@ -0,0 +1,4 @@
+[toolchain]
+channel = "nightly"
+profile = "default"
+components = ["clippy", "rustfmt"]