machine_setup/nix/kubernetes/roles/kubelet/default.nix

{
  config,
  lib,
  pkgs,
  ...
}:

let
  # shellCommand = cmd: (lib.concatMapStringsSep " " lib.strings.escapeShellArg cmd);
  shellCommand = cmd: (builtins.concatStringsSep " " cmd);
  to_yaml_file = ((import ../../functions/to_yaml.nix) { inherit pkgs; }).to_yaml_file;

  kubelet_config = {
    kind = "KubeletConfiguration";
    apiVersion = "kubelet.config.k8s.io/v1beta1";
    address = "0.0.0.0";
    authentication = {
      anonymous = {
        enabled = false;
      };
      webhook = {
        enabled = true;
      };
      x509 = {
        clientCAFile = "/.persist/keys/kube/ca.crt";
      };
    };
    authorization = {
      mode = "Webhook";
    };
    cgroupDriver = "systemd";
    containerRuntimeEndpoint = "unix:///var/run/containerd/containerd.sock";
    enableServer = true;
    failSwapOn = false;
    maxPods = 16;
    memorySwap = {
      swapBehavior = "NoSwap";
    };
    port = 10250;
    resolvConf = "/run/systemd/resolve/resolv.conf";
    registerNode = true;
    runtimeRequestTimeout = "15m";
    tlsCertFile = "/.persist/keys/kube/kubelet.crt";
    tlsPrivateKeyFile = "/.persist/keys/kube/kubelet.key";
    clusterDomain = "cluster.local";
    clusterDNS = [
      "10.197.0.10"
      "fd00:3e42:e349::10"
    ];
  };
  kubelet_config_file = (to_yaml_file "kubelet-config.yaml" kubelet_config);
in
{
  imports = [ ];

  options.me = {
    kubelet.enable = lib.mkOption {
      type = lib.types.bool;
      default = false;
      example = true;
      description = "Whether we want to install kubelet.";
    };
  };

  config = lib.mkIf config.me.kubelet.enable {
    systemd.services.kubelet = {
      enable = true;
      description = "Kubernetes Kubelet";
      documentation = [ "https://github.com/kubernetes/kubernetes" ];
      wantedBy = [ "kubernetes.target" ];
      after = [ "containerd.service" ];
      requires = [ "containerd.service" ];
      path = with pkgs; [
        util-linux
      ];
      unitConfig.DefaultDependencies = "no";
      serviceConfig = {
        ExecStart = (
          shellCommand [
            "${pkgs.kubernetes}/bin/kubelet"
            "--config=${kubelet_config_file}"
            "--kubeconfig=/.persist/keys/kube/kubelet.kubeconfig"
            "--v=2"
          ]
        );
        Restart = "on-failure";
        RestartSec = 5;
        # ConfigurationDirectory = "kubernetes";
        # CPUAccounting = "true";
        # IPAccounting = "true";
        # KillMode = "process";
        # MemoryAccounting = "true";
        # StartLimitInterval = 0;
        # RuntimeDirectory = "kubelet";
        # StateDirectory = "kubelet";
      };
    };

    networking.firewall.allowedTCPPorts = [
      10250
    ];
  };
}