Add a role for loading esims onto standalone sim cards.

nix/configuration/roles/esim/package/easylpac/package.nix

@@ -0,0 +1,68 @@
+{
+  callPackage,
+  go,
+  buildGoModule,
+  fetchFromGitHub,
+  pkg-config,
+  gtk3,
+  libXxf86vm,
+  libglvnd,
+  glfw,
+  wrapGAppsHook3,
+  fontconfig,
+  lpac,
+  lib,
+}:
+
+buildGoModule rec {
+  pname = "easylpac";
+  version = "0.7.9.2";
+  src = fetchFromGitHub {
+    owner = "creamlike1024";
+    repo = "EasyLPAC";
+    rev = version;
+    sha256 = "sha256-8VVR8QJR6SZEvdGls3kDU9l8SdFdUVnHm2qxUzgGJuU=";
+  };
+  proxyVendor = true;
+  vendorHash = "sha256-tX7abWGn1f4p+7vx2gDa5/NKg5SbWqMfHT8kbPwHK14=";
+
+  postConfigure = ''
+    cp --verbose "${./eum-registry.json}" eum-registry.json
+    cp --verbose "${./ci-registry.json}"  ci-registry.json
+  '';
+
+  env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
+
+  nativeBuildInputs = [
+    pkg-config
+    wrapGAppsHook3
+  ];
+  buildInputs = [
+    gtk3
+    libglvnd
+    libXxf86vm
+  ]
+  ++ glfw.buildInputs;
+
+  postInstall = ''
+    ln -s "${lpac}/bin/lpac" "$out/bin/lpac"
+  '';
+
+  passthru = {
+    updateScriptEnabled = true;
+    updateScript =
+      let
+        script = callPackage ./update.nix { };
+      in
+      [ "${script}/bin/update-easylpac" ];
+  };
+
+  meta = with lib; {
+    description = "lpac GUI Frontend";
+    homepage = "https://github.com/creamlike1024/EasyLPAC";
+    mainProgram = "EasyLPAC";
+    license = licenses.mit;
+    maintainers = with maintainers; [ yinfeng ];
+    broken = !(lib.versionAtLeast go.version "1.24");
+  };
+}