Update instawow.

The current version in nixpkgs has not been updated for aiohttp 3.14.

Error: TypeError: ClientResponse.__init__() missing 1 required keyword-only argument: 'stream_writer'

nix/configuration/configuration.nix

@@ -282,6 +282,53 @@ in
         (disableOptimizationsPython3 "zopfli") # /nix/store/idjhlmljrapzm3i1svl5x9mdwfxxj51v-pytest-check-hook/nix-support/setup-hook: line 23:   280 Segmentation fault         (core dumped) /nix/store/87l6i0czch42nzv39ydwld5hnhcq0b65-python3-3.14.7/bin/python3.14 "${flagsArray[@]}"
         (disableOptimizations "zopfli")
         (disableOptimizations "nototools") # Needs to use the same version of python as the zopfli package
+        (final: prev: {
+          instawow = prev.instawow.overrideAttrs (
+            finalAttrs: prevAttrs:
+            let
+              version = "7.2.1";
+            in
+            {
+              inherit version;
+
+              src = final.fetchFromGitHub {
+                owner = "layday";
+                repo = "instawow";
+                tag = "v${finalAttrs.version}";
+                hash = "sha256-5y+oJfzWwaUc3p4fzsQ4j8a6YJEsI+3Qy3gK6VPkjA4=";
+              };
+
+              propagatedBuildInputs = prevAttrs.propagatedBuildInputs ++ [ final.python3.pkgs.versioningit ];
+
+              postPatch = ''
+                # Upstream uses versioningit to set the version
+                sed -i '/^name =.*/a version = "${version}"' pyproject.toml
+                sed -i "/dynamic =/,+2d" pyproject.toml
+              '';
+            }
+          );
+        })
+        (final: prev: {
+          pythonPackagesExtensions = prev.pythonPackagesExtensions ++ [
+            (python-final: python-prev: {
+              aiohttp-client-cache = python-prev.aiohttp-client-cache.overridePythonAttrs (
+                oldAttrs:
+                let
+                  version = "0.15.0";
+                in
+                {
+                  inherit version;
+
+                  src = final.fetchPypi {
+                    pname = "aiohttp_client_cache";
+                    inherit version;
+                    hash = "sha256-Jk+n1pvNsuT+mZTn9Bq17sfLuipfXiYNRE0AL5Ym43Q=";
+                  };
+                }
+              );
+            })
+          ];
+        })
       ];
 
     # This option defines the first version of NixOS you have installed on this particular machine,

nix/configuration/hosts/odo/default.nix

@@ -107,7 +107,7 @@
     me.graphical = true;
     me.graphics_card_type = "amd";
     me.graphviz.enable = true;
-    me.instawow.enable = false;
+    me.instawow.enable = true;
     me.iso_mount.enable = true;
     me.jujutsu.config = ../../roles/jujutsu/files/jujutsu_config_home.toml;
     me.jujutsu.enable = true;

nix/configuration/hosts/quark/default.nix

@@ -100,7 +100,7 @@
     me.graphical = true;
     me.graphics_card_type = "amd";
     me.graphviz.enable = true;
-    me.instawow.enable = false;
+    me.instawow.enable = true;
     me.iso_mount.enable = true;
     me.jujutsu.config = ../../roles/jujutsu/files/jujutsu_config_home.toml;
     me.jujutsu.enable = true;

nix/configuration/roles/instawow/default.nix

@@ -21,5 +21,33 @@
     environment.systemPackages = with pkgs; [
       instawow
     ];
+
+    environment.persistence."/persist" = lib.mkIf (config.me.mountPersistence) {
+      hideMounts = true;
+      users.talexander = {
+        directories = [
+          {
+            directory = ".config/instawow";
+            user = "talexander";
+            group = "talexander";
+            mode = "0755";
+          }
+        ];
+      };
+    };
+
+    environment.persistence."/state" = lib.mkIf (config.me.mountPersistence) {
+      hideMounts = true;
+      users.talexander = {
+        directories = [
+          {
+            directory = ".cache/instawow";
+            user = "talexander";
+            group = "talexander";
+            mode = "0755";
+          }
+        ];
+      };
+    };
   };
 }