Files
machine_setup/nix/configuration/roles/pi_coding_agent/default.nix
2026-11-19 17:16:43 -05:00

68 lines
1.8 KiB
Nix

# Example endpoint when run in qemu with slirp: http://10.0.2.2:8080/v1/chat/completions
{
config,
lib,
pkgs,
...
}:
{
imports = [ ];
options.me = {
pi_coding_agent.enable = lib.mkOption {
type = lib.types.bool;
default = false;
example = true;
description = "Whether we want to install pi_coding_agent.";
};
};
config = lib.mkIf config.me.pi_coding_agent.enable {
environment.systemPackages = with pkgs; [
pi-coding-agent
];
nixpkgs.overlays = [
(final: prev: {
pi-coding-agent = pkgs.symlinkJoin {
name = prev.pi-coding-agent.name;
paths = [ prev.pi-coding-agent ];
buildInputs = [ pkgs.makeWrapper ];
postBuild = ''
wrapProgram $out/bin/pi \
--set-default PI_SKIP_VERSION_CHECK 1 \
--set-default PI_TELEMETRY 0 \
--set-default PI_OFFLINE 1 \
--set-default LLAMA_BASE_URL http://10.0.2.2:8080 \
--set-default LLAMA_API_KEY optional-secret \
--set-default PI_PROVIDER llama.cpp \
--set-default PI_MODEL qwen3.8_27b_bf16
'';
};
})
];
environment.persistence."/persist" = lib.mkIf (config.me.mountPersistence) {
hideMounts = true;
users.talexander = {
directories = [
{
directory = ".pi";
user = "talexander";
group = "talexander";
mode = "0700";
}
{
# For ~/.agents/skills
directory = ".agents";
user = "talexander";
group = "talexander";
mode = "0700";
}
];
};
};
};
}