machine_setup/nix/steam_deck/configuration/roles/shipwright/default.nix

# MANUAL: mkdir -p ~/.persist/.local/share/soh/Save
{
  config,
  lib,
  pkgs,
  ...
}:

let
  steam_shipwright = pkgs.writeScriptBin "steam_soh" ''
    export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${pkgs.libglvnd}/lib"
    exec ${pkgs.shipwright}/bin/soh "''${@}"
  '';
in
{
  imports = [ ];

  options.me = {
    shipwright.enable = lib.mkOption {
      type = lib.types.bool;
      default = false;
      example = true;
      description = "Whether we want to install shipwright.";
    };
  };

  config = lib.mkIf config.me.shipwright.enable (
    lib.mkMerge [
      {
        allowedUnfree = [ "shipwright" ];
      }
      (lib.mkIf config.me.graphical {
        home.packages = with pkgs; [
          shipwright
          steam_shipwright
        ];

        home.file.".local/share/soh/shipofharkinian.json" = {
          source = ./files/shipofharkinian.json;
        };

        home.persistence."/home/deck/.persist" = {
          directories = [
            {
              directory = ".local/share/soh/Save";
              method = "symlink";
            }
          ];
        };
        home.persistence."/home/deck/.state" = {
          files = [
            ".local/share/soh/oot.otr"
          ];
        };

        nixpkgs.overlays = [
          (
            final: prev:
            let
              optimizeWithFlags =
                pkg: flags:
                pkg.overrideAttrs (old: {
                  NIX_CFLAGS_COMPILE = [ (old.NIX_CFLAGS_COMPILE or "") ] ++ flags;
                });
              original_package = prev.shipwright;
              # Optimization is broken for shipwright, fails to build "The following attributes are overlapping"
              # original_package =
              #   if !config.me.optimizations.enable then
              #     (optimizeWithFlags prev.shipwright [
              #       "-march=znver2"
              #       "-mtune=znver2"
              #     ])
              #   else
              #     prev.shipwright;
            in
            {
              shipwright = pkgs.buildEnv {
                name = prev.shipwright.name;
                paths = [
                  (config.lib.nixGL.wrap original_package)
                ];
                extraOutputsToInstall = [
                  "man"
                  "doc"
                  "info"
                ];
                # We have to use 555 instead of the normal 444 here because the .desktop file ends up inside $HOME on steam deck and desktop files must be either not in $HOME or must be executable, otherwise KDE Plasma refuses to execute them.
                postBuild = ''
                  chmod 0555 $out/share/applications/soh.desktop
                '';
              };
            }
          )
        ];
      })
    ]
  );
}